// animated perlin clouds

// use random start position in the 3d noise space
// once initialised, perlin noise has defined fixed values at every coordinate
// so by moving through the space, we can create animations

float yoff=random(1000);
float xoff=random(1000);
float zoff=0;

float xyScale=0.01f;

// constants for the cloud filter
float CLOUD_COVER = 0.55f;
float CLOUD_SHARPNESS = 0.93f;

void setup() {
  size(200,200);
  noiseDetail(8);
}

void loop() {

  // move slowly through the noise space
  // use mouse to steer
  xoff+=((width/2)-mouseX)*0.001;
  yoff+=((height/2)-mouseY)*0.001;
  
  // always move forward
  zoff+=0.05;
  
  // var to store noise value
  int nV;
  
  // reset index in pixel buffer
  int index=0;
  
  // used for speed optimisation
  float currYOff;
  
  for(int y=0; y<height; y++) {
    // noise Y offset only needs to be changed for each scanline
    currYOff=yoff+y*xyScale;
    for(int x=0; x<width; x++) {
      // filter and scale noise to 0..255
      nV=(int)(cloudfilter(noise(xoff+x*xyScale, currYOff, zoff))*255);
      // set pixel value
      // added to gradient background
      pixels[index++]=min(nV+0x90-y/4,0xff)<<16 | min(nV+0xe0-y/2,0xff)<<8 | 0xff;
    }
  }
}

float cloudfilter(float val) {
      return (1-pow(CLOUD_SHARPNESS,max(val-CLOUD_COVER,0)*255));
}