// flexible sphere resolutions
// author: info@toxi.co.uk
// converted from lingo (http://www.toxi.co.uk/zips/meshlib.zip)

float[] cx,cz,sphereX,sphereY,sphereZ;

int currRes=0;
boolean filled=true;

void setup() {
  size(400,400);
}

void loop() {
  background(200);
  translate(100+mouseX/2,mouseY,-100);
  rotateX(mouseY*0.02);
  rotateY(mouseX*0.01);
  if (filled) {
    fill(mouseX/1.5,0,160);
    stroke(255,30);
  } else {
    noFill();
    stroke(0,30);
  }
  xsphere(mouseY,3+mouseX/6);
}

void mouseReleased() {
  filled=!filled;
}

void xsphere(float radius,  int res) {
  float delta=360f/res;
  float rad=PI/180;
  if (res!=currRes) {
    cx=new float[res];
    cz=new float[res];
    // calc unit circle
    for(int i=0; i<res; i++) {
      cx[i]=cos(i*delta*rad);
      cz[i]=sin(i*delta*rad);
    }
    // computing vertexlist
    // vertexlist starts at south pole
    int vertCount=res*(res-1)+2;
    int currVert=0;

    sphereX=new float[vertCount];
    sphereY=new float[vertCount];
    sphereZ=new float[vertCount];

    // radius angle is used for scaling circle
    float angle_step=180.0/res;
    float angle=angle_step;
    float[] ringVertsX=new float[res];
    float[] ringVertsZ=new float[res];

    for(int i=1; i<res; i++) {
      float curradius=sin(angle*rad);
      float currY=-cos(angle*rad);
      for(int j=0; j<res; j++) {
        sphereX[currVert]=cx[j]*curradius;
        sphereY[currVert]=currY;
        sphereZ[currVert++]=cz[j]*curradius;
      }
      angle+=angle_step;
    }
    currRes=res;
  }

  int v1,v2,v3,v4;
  push();
  scale(radius);
  beginShape(TRIANGLES);
  // 1st ring from south pole
  for(int i=1; i<=res; i++) {
    v2=i%res;
    v3=(i+1)%res;
    vertex(0,-1,0);
    vertex(sphereX[v2],sphereY[v2],sphereZ[v2]);
    vertex(sphereX[v3],sphereY[v3],sphereZ[v3]);
  }

  // middle rings
  int voff=res;
  for(int i=1; i<res-1; i++) {
    for(int j=0; j<res; j++) {
      v1=voff-res+j;
      v2=voff+j;
      v3=(j+1)%res+voff;
      v4=voff-res+(j+1)%res;
      vertex(sphereX[v1],sphereY[v1],sphereZ[v1]);
      vertex(sphereX[v2],sphereY[v2],sphereZ[v2]);
      vertex(sphereX[v3],sphereY[v3],sphereZ[v3]);
      // 2nd part of quad
      vertex(sphereX[v1],sphereY[v1],sphereZ[v1]);
      vertex(sphereX[v3],sphereY[v3],sphereZ[v3]);
      vertex(sphereX[v4],sphereY[v4],sphereZ[v4]);
    }
    voff+=res;
  }
  // undo the last update
  voff-=res;
  // add the northern cap
  for(int i=1; i<=res; i++) {
    v2=voff+i%res;
    v3=voff+(i+1)%res;
    vertex(0,1,0);
    vertex(sphereX[v2],sphereY[v2],sphereZ[v2]);
    vertex(sphereX[v3],sphereY[v3],sphereZ[v3]);
  }
  endShape();
  pop();
}